buildscript {
    repositories {
        google()
        mavenCentral()
    }

    dependencies {
        // AGP y Kotlin se declaran en settings.gradle (plugins DSL); aquí solo
        // queda google-services, que no está en ese bloque.
        classpath 'com.google.gms:google-services:4.3.4'
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
    }

    // sentry_flutter 8.x fija languageVersion = "1.6" en su build.gradle y Kotlin
    // 2.2 ya no la admite ("Language version 1.6 is no longer supported"). Este
    // override es lo que mantiene compilables los plugins con ajustes antiguos.
    plugins.withId('kotlin-android') {
        tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).configureEach {
            kotlinOptions {
                languageVersion = '1.9'
                allWarningsAsErrors = false
            }
        }
    }
}

rootProject.buildDir = '../build'
subprojects {
    project.buildDir = "${rootProject.buildDir}/${project.name}"
}
subprojects {
    project.evaluationDependsOn(':app')
}

tasks.register("clean", Delete) {
    delete rootProject.layout.buildDirectory
}